访问电脑版页面

导航:老古开发网手机版51单片机与I2C总线

51单片机对SAA7113初始化和控制的程序

导读:
关键字:
SAA7113,51,

  用51单片机对7113初始化和控制

  SAA7113的初始化就是对寄存器配置合适的参数,使其能够有符合要求的输出。寄存器配置通过I2C总线来进行,很多可以控制I2C总线的器件都可以作为主器件对7113进行初始化,这里介绍用51单片机初始化7113的例子。

  用单片机初始化7113的主要任务是程序的编写,首先要熟悉I2C总线协议,根据I2C总线的原理写出启动、停止、应答信号等的子程序,由子程序再写出发送、接收1个字节的程序,然后根据7113的寄存器操作格式写出读写寄存器的程序,最后根据以上的子程序写出初始化7113的程序段。

  对7113的控制一般是改变色度、亮度等指标以及输出管脚的输出信号,这可以通过修改相应寄存器的值来完成,程序上写出“读写命令”即可。

  下面以程序段的形式给出初始化SAA7113以及读写寄存器的具体例子,以供参考。

  SDA BIT P1.0

  SCL BIT P1.1

  I2C_ERROR BIT 00H ;I2C总线数据传输出错标志

  DeviceaddressW EQU 4AH ;7113器件地址+写

  DeviceaddressR EQU 4BH ;7113器件地址+读

  Subaddress EQU 4DH ;7113寄存器地址字节在单片机中的存放地址

  DATA_I2C EQU 50H ;设置写入或读出数据在单片机中的存放地址

  ;*************启动**************

  I2C_START: SETB SDA

  NOP

  SETB SCL

  NOP

  CLR SDA

  NOP

  CLR SCL

  RET

  ;***************停止**************

  I2C_STOP: CLR SDA

  NOP

  SETB SCL

  NOP

  SETB SDA

  NOP

  RET

  ;************送应答位************

  SEND_ACK: CLR SCL

  NOP

  CLR SDA

  NOP

  SETB SCL

  NOP

  ?NOP

  CLR SCL

  NOP

  SETB SDA

  RET

  ;***********送非应答位***********

  SEND_NOACK: SETB SDA

  NOP

  SETB SCL

  NOP

  NOP

  CLR SCL

  NOP

  RET

  ;***********检查应答位************

  CHECK_ACK: NOP

  CLR SCL

  NOP

  SETB SDA

  NOP

  SETB SCL

  NOP

  NOP

  MOV C, SDA

  MOV I2C_ERROR, C

  CLR SCL

  NOP

  RET

  ;*******发送1字节数据,待送数据在A中******

  I2C_SEND_1BYTE:

  MOV R0, #8

  SEND100: RLC A

  MOV SDA, C

  NOP

  SETB SCL

  NOP

  NOP

  CLR SCL

  DJNZ R0, SEND100

  RET

  ;*******接收1字节数据,接收数据放在A中*****

  I2C_RECEIVE_1BYTE:

  MOV R0, #8

  RECV100: SETB SDA

  NOP

  SETB SCL

  NOP

  NOP

  NOP

  MOV C, SDA

  CLR SCL

  RLC A

  DJNZ R0, RECV100

  RET

  ;*******通过I2C总线向某一寄存器写入一个字节数据*********

  I2C_WRITE: ACALL I2C_START ;发启动信号

  MOV A, # DeviceaddressW ;调7113地址+写

  ACALL I2C_SEND_1BYTE ;发送7113地址及“写”命令

  ACALL CHECK_ACK ;检查7113的应答信号

  JNB I2C_ERROR, WR200 ;应答正确,继续

  WR100: ACALL I2C_STOP ;应答不对,返回

  RET

  WR200: MOV A, Subaddress ;调寄存器地址

  ACALL I2C_SEND_1BYTE ;发送寄存器地址

  ACALL CHECK_ACK ;检查7113的应答信号

  JB I2C_ERROR, WR100 ;应答不对,返回

  MOV A, DATA_I2C ;调准备写入的数据

  ACALL I2C_SEND_1BYTE ;发送数据字节

  ACALL CHECK_ACK

  JB I2C_ERROR, WR100

  ACALL I2C_STOP ;发停止信号

  RET

  ;*******通过I2C总线读出某一寄存器的数据*********

  I2C_READ: ACALL I2C_START

  MOV A, # DeviceaddressW ;调7113地址,写入

  ACALL I2C_SEND_1BYTE

  ACALL CHECK_ACK

  JNB I2C_ERROR, RD200

  RD100: ACALL I2C_STOP

  RET

  RD200: MOV A, Subaddress ;调要读的寄存器地址

  ACALL I2C_SEND_1BYTE ; 发送寄存器地址字节

  ACALL CHECK_ACK

  JB I2C_ERROR, RD100

  ACALL I2C_START ;重发起动信号

  MOV A, # DeviceaddressR ;调7113地址,读

  ACALL I2C_SEND_1BYTE

  ACALL CHECK_ACK

  JB I2C_ERROR, RD100

  ACALL I2C_RECEIVE_1BYTE ;接收读出的数据

  MOV DATA_I2C,A ;读出数据转存

  ACALL SEND_NOACK ;发送非应答位

  ACALL I2C_STOP ;停止

  RET

  ;***************初始化7113,配置各寄存器************************

  INIT_SAA7113: MOV DPTR, #SAA7113_Subaddress

  MOV R7, #28

  INIT100: MOV A, #0

  MOV C A, @A+DPTR

  MOV Subaddress, A ;调寄存器地址

  MOV A,#28

  MOVC A, @A+DPTR

  MOV DATA_I2C, A ;调寄存器配置数据

  INC DPTR

  ACALL I2C_WRITE ;配置1个寄存器

  JB I2C_ERROR, INIT200

  DJNZ R7,INIT100

  INIT200: RET

  ;***************SAA7113寄存器初始化配置数据**********************

  SAA7113_Subaddress:

  DB 01H,02H,03H,04H,05H,06H,07H,08H,09H,0AH,0BH,0CH,0DH,0EH

  DB 0FH,10H,11H,12H,13H,15H,16H,17H,40H,58H,59H,5AH,5BH,5EH

  ;共28个

  I2C_REG_VALUE_AI11:

  DB 08H,0C0H,33H,00H,00H,0EBH,0E0H,0B8H,01H,7EH,46H,43H,01H,01H

  DB 0FH,00H,0CH,0A7H,00H,00H,00H,00H,02H,00H,54H,07H,80H,00H

  ;*************对SAA7113某一寄存器的改写与读出*******************

  WRITE_READ: MOV Subaddress, #0AH ; 设寄存器地址为0AH

  MOV DATA_I2C, #88H ;改寄存器的值为88H

  ACALL I2C_WRITE ;改写

  ACALL I2C_READ ;读出

来源:www.elecfans.com   作者:本站  2010/9/8 11:50:00
栏目: [ 51单片机与I2C总线]

相关阅读

8051单片机的I2C接口并行扩展

51单片机模拟I2C总线的C语言实现

24C512程序

基于51单片机i2c多字节的读写

大神教你快速上手:标准80C51单片机模拟I2C总线的主机程序

51单片机——I2C总线

51单片机对SAA7113初始化和控制的程序

51单片机连接24C02-C语言测试代码

如何采用C51单片机读写CAT24C32

80C51单片机模拟I2C总线的主机程序分享

如何用51单片机实现IIC通信

如何采用51单片机连接24C02-C语言测试代码

51单片机模拟I2C总线程序